Safe Zone Protection

Nutzt Marker, die entsprechend existent und benannt werden sollten. Original by [SeL] Sinus:

// spawn protection by deleting projectiles fired by players near respawn pos
if (["UseSafeZone", 0] call BIS_fnc_getParamValue isEqualTo 1) then {
    sin_spawnProtectPos = getMarkerPos "respawn_west";

    if (playersNumber east > playersNumber west) then {
        sin_spawnProtectPos = getMarkerPos "respawn_east";
    };

    if ((playersNumber independent > playersNumber west) && (playersNumber independent > playersNumber east)) then {
        sin_spawnProtectPos = getMarkerPos "respawn_guerrila";
    };

    ["CAManBase", "Fired", {
        params ["_unit", "_weapon", "_muzzle", "_mode", "_ammo", "_magazine", "_projectile", "_gunner"];

        if (isPlayer _unit) then {
            if ((_unit distance2D sin_spawnProtectPos) < 75) then {
                deleteVehicle _projectile;

                if (_weapon isEqualTo "Throw") then {
                    _unit addMagazine [_magazine, 1];
                };
            };
        };
    }] call CBA_fnc_addClassEventHandler;
};